with System.Storage_Elements;
with System.Soft_Links;
with Unchecked_Conversion;
package body System.Pool_Size is
package SSE renames System.Storage_Elements;
use type SSE.Storage_Offset;
package SSL renames System.Soft_Links;
type Storage_Count_Access is access SSE.Storage_Count;
function To_Storage_Count_Access is
new Unchecked_Conversion (Address, Storage_Count_Access);
SC_Size : constant := SSE.Storage_Count'Object_Size / System.Storage_Unit;
package Variable_Size_Management is
procedure Initialize (Pool : in out Stack_Bounded_Pool);
procedure Allocate
(Pool : in out Stack_Bounded_Pool;
Address : out System.Address;
Storage_Size : SSE.Storage_Count;
Alignment : SSE.Storage_Count);
procedure Deallocate
(Pool : in out Stack_Bounded_Pool;
Address : System.Address;
Storage_Size : SSE.Storage_Count;
Alignment : SSE.Storage_Count);
end Variable_Size_Management;
package Vsize renames Variable_Size_Management;
procedure Allocate
(Pool : in out Stack_Bounded_Pool;
Address : out System.Address;
Storage_Size : SSE.Storage_Count;
Alignment : SSE.Storage_Count)
is
begin
SSL.Lock_Task.all;
if Pool.Elmt_Size = 0 then
Vsize.Allocate (Pool, Address, Storage_Size, Alignment);
elsif Pool.First_Free /= 0 then
Address := Pool.The_Pool (Pool.First_Free)'Address;
Pool.First_Free := To_Storage_Count_Access (Address).all;
elsif
Pool.First_Empty <= (Pool.Pool_Size - Pool.Aligned_Elmt_Size + 1)
then
Address := Pool.The_Pool (Pool.First_Empty)'Address;
Pool.First_Empty := Pool.First_Empty + Pool.Aligned_Elmt_Size;
else
raise Storage_Error;
end if;
SSL.Unlock_Task.all;
exception
when others =>
SSL.Unlock_Task.all;
raise;
end Allocate;
procedure Deallocate
(Pool : in out Stack_Bounded_Pool;
Address : System.Address;
Storage_Size : SSE.Storage_Count;
Alignment : SSE.Storage_Count)
is
begin
SSL.Lock_Task.all;
if Pool.Elmt_Size = 0 then
Vsize.Deallocate (Pool, Address, Storage_Size, Alignment);
else
To_Storage_Count_Access (Address).all := Pool.First_Free;
Pool.First_Free := Address - Pool.The_Pool'Address + 1;
end if;
SSL.Unlock_Task.all;
exception
when others =>
SSL.Unlock_Task.all;
raise;
end Deallocate;
procedure Initialize (Pool : in out Stack_Bounded_Pool) is
Align : constant SSE.Storage_Count :=
SSE.Storage_Count'Max
(SSE.Storage_Count'Alignment, Pool.Alignment);
begin
if Pool.Elmt_Size = 0 then
Vsize.Initialize (Pool);
else
Pool.First_Free := 0;
Pool.First_Empty := 1;
Pool.Aligned_Elmt_Size :=
SSE.Storage_Count'Max (SC_Size,
((Pool.Elmt_Size + Align - 1) / Align) * Align);
end if;
end Initialize;
function Storage_Size
(Pool : Stack_Bounded_Pool) return SSE.Storage_Count
is
begin
return Pool.Pool_Size;
end Storage_Size;
package body Variable_Size_Management is
Minimum_Size : constant := 2 * SC_Size;
procedure Set_Size
(Pool : Stack_Bounded_Pool;
Chunk, Size : SSE.Storage_Count);
procedure Set_Next
(Pool : Stack_Bounded_Pool;
Chunk, Next : SSE.Storage_Count);
function Size
(Pool : Stack_Bounded_Pool;
Chunk : SSE.Storage_Count) return SSE.Storage_Count;
function Next
(Pool : Stack_Bounded_Pool;
Chunk : SSE.Storage_Count) return SSE.Storage_Count;
function Chunk_Of
(Pool : Stack_Bounded_Pool;
Addr : System.Address) return SSE.Storage_Count;
procedure Allocate
(Pool : in out Stack_Bounded_Pool;
Address : out System.Address;
Storage_Size : SSE.Storage_Count;
Alignment : SSE.Storage_Count)
is
Chunk : SSE.Storage_Count;
New_Chunk : SSE.Storage_Count;
Prev_Chunk : SSE.Storage_Count;
Our_Align : constant SSE.Storage_Count :=
SSE.Storage_Count'Max (SSE.Storage_Count'Alignment,
Alignment);
Align_Size : constant SSE.Storage_Count :=
SSE.Storage_Count'Max (
Minimum_Size,
((Storage_Size + Our_Align - 1) / Our_Align) *
Our_Align);
begin
Prev_Chunk := Pool.First_Free;
Chunk := Next (Pool, Prev_Chunk);
while Chunk /= 0 and then Size (Pool, Chunk) < Align_Size loop
Prev_Chunk := Chunk;
Chunk := Next (Pool, Chunk);
end loop;
if Chunk = 0 then
raise Storage_Error;
end if;
if Size (Pool, Chunk) - Align_Size > Minimum_Size then
New_Chunk := Chunk + Align_Size;
Set_Size (Pool, New_Chunk, Size (Pool, Chunk) - Align_Size);
Set_Next (Pool, New_Chunk, Next (Pool, Chunk));
Set_Next (Pool, Prev_Chunk, New_Chunk);
else
Set_Next (Pool, Prev_Chunk, Next (Pool, Chunk));
end if;
Address := Pool.The_Pool (Chunk)'Address;
end Allocate;
function Chunk_Of
(Pool : Stack_Bounded_Pool;
Addr : System.Address) return SSE.Storage_Count
is
begin
return 1 + abs (Addr - Pool.The_Pool (1)'Address);
end Chunk_Of;
procedure Deallocate
(Pool : in out Stack_Bounded_Pool;
Address : System.Address;
Storage_Size : SSE.Storage_Count;
Alignment : SSE.Storage_Count)
is
Align_Size : constant SSE.Storage_Count :=
((Storage_Size + Alignment - 1) / Alignment) *
Alignment;
Chunk : constant SSE.Storage_Count := Chunk_Of (Pool, Address);
begin
Set_Size (Pool, Chunk,
SSE.Storage_Count'Max (Align_Size, Minimum_Size));
Set_Next (Pool, Chunk, Next (Pool, Pool.First_Free));
Set_Next (Pool, Pool.First_Free, Chunk);
end Deallocate;
procedure Initialize (Pool : in out Stack_Bounded_Pool) is
begin
Pool.First_Free := 1;
if Pool.Pool_Size > Minimum_Size then
Set_Next (Pool, Pool.First_Free, Pool.First_Free + Minimum_Size);
Set_Size (Pool, Pool.First_Free, 0);
Set_Size (Pool, Pool.First_Free + Minimum_Size,
Pool.Pool_Size - Minimum_Size);
Set_Next (Pool, Pool.First_Free + Minimum_Size, 0);
end if;
end Initialize;
function Next
(Pool : Stack_Bounded_Pool;
Chunk : SSE.Storage_Count) return SSE.Storage_Count
is
begin
pragma Warnings (Off);
return To_Storage_Count_Access
(Pool.The_Pool (Chunk + SC_Size)'Address).all;
pragma Warnings (On);
end Next;
procedure Set_Next
(Pool : Stack_Bounded_Pool;
Chunk, Next : SSE.Storage_Count)
is
begin
pragma Warnings (Off);
To_Storage_Count_Access
(Pool.The_Pool (Chunk + SC_Size)'Address).all := Next;
pragma Warnings (On);
end Set_Next;
procedure Set_Size
(Pool : Stack_Bounded_Pool;
Chunk, Size : SSE.Storage_Count)
is
begin
pragma Warnings (Off);
To_Storage_Count_Access
(Pool.The_Pool (Chunk)'Address).all := Size;
pragma Warnings (On);
end Set_Size;
function Size
(Pool : Stack_Bounded_Pool;
Chunk : SSE.Storage_Count) return SSE.Storage_Count
is
begin
pragma Warnings (Off);
return To_Storage_Count_Access (Pool.The_Pool (Chunk)'Address).all;
pragma Warnings (On);
end Size;
end Variable_Size_Management;
end System.Pool_Size;