(eval-when-compile
(require 'cl)
(require 'vc))
(defcustom vc-rcs-release nil
"*The release number of your RCS installation, as a string.
If nil, VC itself computes this value when it is first needed."
:type '(choice (const :tag "Auto" nil)
(string :tag "Specified")
(const :tag "Unknown" unknown))
:group 'vc)
(defcustom vc-rcs-register-switches nil
"*Extra switches for registering a file in RCS.
A string or list of strings. These are passed to the checkin program
by \\[vc-rcs-register]."
:type '(choice (const :tag "None" nil)
(string :tag "Argument String")
(repeat :tag "Argument List"
:value ("")
string))
:version "21.1"
:group 'vc)
(defcustom vc-rcs-diff-switches nil
"*A string or list of strings specifying extra switches for rcsdiff under VC."
:type '(choice (const :tag "None" nil)
(string :tag "Argument String")
(repeat :tag "Argument List"
:value ("")
string))
:version "21.1"
:group 'vc)
(defcustom vc-rcs-header (or (cdr (assoc 'RCS vc-header-alist)) '("\$Id\$"))
"*Header keywords to be inserted by `vc-insert-headers'."
:type '(repeat string)
:version "21.1"
:group 'vc)
(defcustom vc-rcsdiff-knows-brief nil
"*Indicates whether rcsdiff understands the --brief option.
The value is either `yes', `no', or nil. If it is nil, VC tries
to use --brief and sets this variable to remember whether it worked."
:type '(choice (const :tag "Work out" nil) (const yes) (const no))
:group 'vc)
(defcustom vc-rcs-master-templates
'("%sRCS/%s,v" "%s%s,v" "%sRCS/%s")
"*Where to look for RCS master files.
For a description of possible values, see `vc-check-master-templates'."
:type '(choice (const :tag "Use standard RCS file names"
'("%sRCS/%s,v" "%s%s,v" "%sRCS/%s"))
(repeat :tag "User-specified"
(choice string
function)))
:version "21.1"
:group 'vc)
(defun vc-rcs-registered (f) (vc-default-registered 'RCS f))
(defun vc-rcs-state (file)
"Implementation of `vc-state' for RCS."
(or (boundp 'vc-rcs-headers-result)
(and vc-consult-headers
(vc-rcs-consult-headers file)))
(let ((state
(vc-rcs-fetch-master-state file
(vc-file-getprop file
'vc-workfile-version))))
(if (not (eq state 'up-to-date))
state
(if (vc-workfile-unchanged-p file)
'up-to-date
(if (eq (vc-checkout-model file) 'locking)
'unlocked-changes
'edited)))))
(defun vc-rcs-state-heuristic (file)
"State heuristic for RCS."
(let (vc-rcs-headers-result)
(if (and vc-consult-headers
(setq vc-rcs-headers-result
(vc-rcs-consult-headers file))
(eq vc-rcs-headers-result 'rev-and-lock))
(let ((state (vc-file-getprop file 'vc-state)))
(if (and (eq state 'up-to-date)
(not (vc-mistrust-permissions file)))
(cond
((string-match ".rw..-..-." (nth 8 (file-attributes file)))
(vc-file-setprop file 'vc-checkout-model 'implicit)
(setq state
(if (vc-rcs-workfile-is-newer file)
'edited
'up-to-date)))
((string-match ".r-..-..-." (nth 8 (file-attributes file)))
(vc-file-setprop file 'vc-checkout-model 'locking))))
state)
(if (not (vc-mistrust-permissions file))
(let* ((attributes (file-attributes file 'string))
(owner-name (nth 2 attributes))
(permissions (nth 8 attributes)))
(cond ((string-match ".r-..-..-." permissions)
(vc-file-setprop file 'vc-checkout-model 'locking)
'up-to-date)
((string-match ".rw..-..-." permissions)
(if (eq (vc-checkout-model file) 'locking)
(if (file-ownership-preserved-p file)
'edited
owner-name)
(if (vc-rcs-workfile-is-newer file)
'edited
'up-to-date)))
(t
(vc-rcs-state file))))
(vc-rcs-state file)))))
(defun vc-rcs-workfile-version (file)
"RCS-specific version of `vc-workfile-version'."
(or (and vc-consult-headers
(vc-rcs-consult-headers file)
(vc-file-getprop file 'vc-workfile-version))
(progn
(vc-rcs-fetch-master-state file)
(vc-file-getprop file 'vc-workfile-version))))
(defun vc-rcs-latest-on-branch-p (file &optional version)
"Return non-nil if workfile version of FILE is the latest on its branch.
When VERSION is given, perform check for that version."
(unless version (setq version (vc-workfile-version file)))
(with-temp-buffer
(string= version
(if (vc-trunk-p version)
(progn
(vc-insert-file (vc-name file) "^[0-9]")
(vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
(vc-insert-file (vc-name file) "^desc")
(vc-rcs-find-most-recent-rev (vc-branch-part version))))))
(defun vc-rcs-checkout-model (file)
"RCS-specific version of `vc-checkout-model'."
(let (result)
(when vc-consult-headers
(vc-file-setprop file 'vc-checkout-model nil)
(vc-rcs-consult-headers file)
(setq result (vc-file-getprop file 'vc-checkout-model)))
(or result
(progn (vc-rcs-fetch-master-state file)
(vc-file-getprop file 'vc-checkout-model)))))
(defun vc-rcs-workfile-unchanged-p (file)
"RCS-specific implementation of `vc-workfile-unchanged-p'."
(let* ((version (concat "-r" (vc-workfile-version file)))
(status (if (eq vc-rcsdiff-knows-brief 'no)
(vc-do-command nil 1 "rcsdiff" file version)
(vc-do-command nil 2 "rcsdiff" file "--brief" version))))
(if (eq status 2)
(if (not vc-rcsdiff-knows-brief)
(setq vc-rcsdiff-knows-brief 'no
status (vc-do-command nil 1 "rcsdiff" file version))
(error "rcsdiff failed"))
(if (not vc-rcsdiff-knows-brief) (setq vc-rcsdiff-knows-brief 'yes)))
(zerop status)))
(defun vc-rcs-register (file &optional rev comment)
"Register FILE into the RCS version-control system.
REV is the optional revision number for the file. COMMENT can be used
to provide an initial description of FILE.
`vc-register-switches' and `vc-rcs-register-switches' are passed to
the RCS command (in that order).
Automatically retrieve a read-only version of the file with keywords
expanded if `vc-keep-workfiles' is non-nil, otherwise, delete the workfile."
(let ((subdir (expand-file-name "RCS" (file-name-directory file))))
(and (not (file-exists-p subdir))
(not (directory-files (file-name-directory file)
nil ".*,v$" t))
(yes-or-no-p "Create RCS subdirectory? ")
(make-directory subdir))
(apply 'vc-do-command nil 0 "ci" file
(and (vc-rcs-release-p "5.6.4") "-i")
(concat (if vc-keep-workfiles "-u" "-r") rev)
(and comment (concat "-t-" comment))
(vc-switches 'RCS 'register))
(with-current-buffer "*vc*"
(goto-char (point-min))
(let ((name (if (looking-at (concat "^\\(.*\\) <-- "
(file-name-nondirectory file)))
(match-string 1))))
(if (not name)
(vc-rcs-registered file)
(vc-file-setprop file 'vc-name
(if (file-name-absolute-p name)
name
(expand-file-name
name
(file-name-directory file))))))
(vc-file-setprop file 'vc-workfile-version
(if (re-search-forward
"^initial revision: \\([0-9.]+\\).*\n"
nil t)
(match-string 1))))))
(defun vc-rcs-responsible-p (file)
"Return non-nil if RCS thinks it would be responsible for registering FILE."
(file-directory-p (expand-file-name "RCS" (file-name-directory file))))
(defun vc-rcs-receive-file (file rev)
"Implementation of receive-file for RCS."
(let ((checkout-model (vc-checkout-model file)))
(vc-rcs-register file rev "")
(when (eq checkout-model 'implicit)
(vc-rcs-set-non-strict-locking file))
(vc-rcs-set-default-branch file (concat rev ".1"))))
(defun vc-rcs-unregister (file)
"Unregister FILE from RCS.
If this leaves the RCS subdirectory empty, ask the user
whether to remove it."
(let* ((master (vc-name file))
(dir (file-name-directory master))
(backup-info (find-backup-file-name master)))
(if (not backup-info)
(delete-file master)
(rename-file master (car backup-info) 'ok-if-already-exists)
(dolist (f (cdr backup-info)) (ignore-errors (delete-file f))))
(and (string= (file-name-nondirectory (directory-file-name dir)) "RCS")
(not (directory-files dir nil
"^\\([^.]\\|\\.[^.]\\|\\.\\.[^.]\\).*"))
(yes-or-no-p (format "Directory %s is empty; remove it? " dir))
(delete-directory dir))))
(defun vc-rcs-checkin (file rev comment)
"RCS-specific version of `vc-backend-checkin'."
(let ((switches (vc-switches 'RCS 'checkin)))
(let ((old-version (vc-workfile-version file)) new-version
(default-branch (vc-file-getprop file 'vc-rcs-default-branch)))
(and (not rev)
default-branch
(string-match (concat "^" (regexp-quote old-version) "\\.")
default-branch)
(setq rev default-branch)
(setq switches (cons "-f" switches)))
(if (and (not rev) old-version)
(setq rev (vc-branch-part old-version)))
(apply 'vc-do-command nil 0 "ci" (vc-name file)
(and (vc-rcs-release-p "5.6.4") "-j")
(concat (if vc-keep-workfiles "-u" "-r") rev)
(concat "-m" comment)
switches)
(vc-file-setprop file 'vc-workfile-version nil)
(set-buffer "*vc*")
(goto-char (point-min))
(when (or (re-search-forward
"new revision: \\([0-9.]+\\);" nil t)
(re-search-forward
"reverting to previous revision \\([0-9.]+\\)" nil t))
(setq new-version (match-string 1))
(vc-file-setprop file 'vc-workfile-version new-version))
(cond
((and old-version new-version
(not (string= (vc-branch-part old-version)
(vc-branch-part new-version))))
(vc-rcs-set-default-branch file
(if (vc-trunk-p new-version) nil
(vc-branch-part new-version)))
(if (not (vc-rcs-release-p "5.6.2"))
(vc-do-command nil 1 "rcs" (vc-name file)
(concat "-u" old-version))))))))
(defun vc-rcs-find-version (file rev buffer)
(apply 'vc-do-command
buffer 0 "co" (vc-name file)
"-q" (concat "-p" rev)
(vc-switches 'RCS 'checkout)))
(defun vc-rcs-checkout (file &optional editable rev)
"Retrieve a copy of a saved version of FILE."
(let ((file-buffer (get-file-buffer file))
switches)
(message "Checking out %s..." file)
(save-excursion
(if file-buffer (set-buffer file-buffer))
(setq switches (vc-switches 'RCS 'checkout))
(let ((default-directory default-directory))
(save-excursion
(setq default-directory (file-name-directory file))
(let (new-version)
(and rev (string= rev "")
(vc-rcs-set-default-branch file nil))
(apply 'vc-do-command
nil 0 "co" (vc-name file)
(if (eq (vc-checkout-model file) 'implicit) "-f")
(if editable "-l")
(if (stringp rev)
(concat "-r" rev)
(let ((workrev (vc-workfile-version file)))
(if workrev
(concat "-r"
(if (not rev)
workrev
(if (not (vc-trunk-p workrev))
(vc-branch-part workrev)
(vc-rcs-set-default-branch file
nil)
""))))))
switches)
(with-current-buffer "*vc*"
(setq new-version
(vc-parse-buffer "^revision \\([0-9.]+\\).*\n" 1)))
(vc-file-setprop file 'vc-workfile-version new-version)
(and rev (not (string= rev ""))
(vc-rcs-set-default-branch
file
(if (vc-rcs-latest-on-branch-p file new-version)
(if (vc-trunk-p new-version) nil
(vc-branch-part new-version))
new-version)))))
(message "Checking out %s...done" file)))))
(defun vc-rcs-revert (file &optional contents-done)
"Revert FILE to the version it was based on."
(vc-do-command nil 0 "co" (vc-name file) "-f"
(concat (if (eq (vc-state file) 'edited) "-u" "-r")
(vc-workfile-version file))))
(defun vc-rcs-cancel-version (file editable)
"Undo the most recent checkin of FILE.
EDITABLE non-nil means previous version should be locked."
(let* ((target (vc-workfile-version file))
(previous (if (vc-trunk-p target) "" (vc-branch-part target)))
(config (current-window-configuration))
(done nil))
(vc-do-command nil 0 "rcs" (vc-name file) (concat "-o" target))
(while (not done)
(condition-case err
(progn
(vc-do-command nil 0 "co" (vc-name file) "-f"
(concat (if editable "-l" "-u") previous))
(setq done t))
(error (set-buffer "*vc*")
(goto-char (point-min))
(if (search-forward "no side branches present for" nil t)
(progn (setq previous (vc-branch-part previous))
(vc-rcs-set-default-branch file previous)
(set-window-configuration config))
(signal (car err) (cdr err))))))))
(defun vc-rcs-merge (file first-version &optional second-version)
"Merge changes into current working copy of FILE.
The changes are between FIRST-VERSION and SECOND-VERSION."
(vc-do-command nil 1 "rcsmerge" (vc-name file)
"-kk" (concat "-r" first-version)
(if second-version (concat "-r" second-version))))
(defun vc-rcs-steal-lock (file &optional rev)
"Steal the lock on the current workfile for FILE and revision REV.
Needs RCS 5.6.2 or later for -M."
(vc-do-command nil 0 "rcs" (vc-name file) "-M" (concat "-u" rev))
(vc-do-command nil 0 "co" (vc-name file) "-f" (concat "-l" rev)))
(defun vc-rcs-print-log (file &optional buffer)
"Get change log associated with FILE."
(vc-do-command buffer 0 "rlog" (vc-name file)))
(defun vc-rcs-diff (file &optional oldvers newvers buffer)
"Get a difference report using RCS between two versions of FILE."
(if (not oldvers) (setq oldvers (vc-workfile-version file)))
(apply 'vc-do-command (or buffer "*vc-diff*") 1 "rcsdiff" file
(append (list "-q"
(concat "-r" oldvers)
(and newvers (concat "-r" newvers)))
(vc-switches 'RCS 'diff))))
(defun vc-rcs-annotate-command (file buffer &optional revision)
"Annotate FILE, inserting the results in BUFFER.
Optional arg REVISION is a revision to annotate from."
(vc-setup-buffer buffer)
(let* ((tree (with-temp-buffer
(insert-file-contents (vc-rcs-registered file))
(vc-rcs-parse)))
(revisions (cdr (assq 'revisions tree)))
(cur (cdr (assq 'head (cdr (assq 'headers tree)))))
(meta (cdr (assoc cur revisions)))
p s
nbls
prda
path
pre)
(unless revision
(setq revision cur))
(unless (assoc revision revisions)
(error "No such revision: %s" revision))
(let ((par revision)
bpt kids)
(while (setq bpt (vc-branch-part par)
par (vc-branch-part bpt))
(setq kids (cdr (assq 'branches (cdr (assoc par revisions)))))
(while (not (string= bpt (vc-branch-part (car kids))))
(setq kids (cdr kids)))
(push (cons par (car kids)) nbls)))
(set-buffer buffer)
(insert (cdr (assq 'text meta)))
(flet ((r/d/a () (vector pre
(cdr (assq 'date meta))
(cdr (assq 'author meta)))))
(while (when (setq pre cur cur (cdr (assq 'next meta)))
(not (string= "" cur)))
(setq
prda (when (or prda (string= (if nbls (caar nbls) revision) pre))
(r/d/a))
meta (cdr (assoc cur revisions)))
(dolist (insn (cdr (assq :insn meta)))
(goto-line (pop insn))
(setq p (point))
(case (pop insn)
(k (setq s (buffer-substring-no-properties
p (progn (forward-line (car insn))
(point))))
(when prda
(push `(,p . ,(propertize s :vc-rcs-r/d/a prda)) path))
(delete-region p (point)))
(i (setq s (car insn))
(when prda
(push `(,p . ,(length s)) path))
(insert s)))))
(put-text-property (point-min) (point-max) :vc-rcs-r/d/a (r/d/a))
(dolist (insn path)
(goto-char (pop insn))
(if (stringp insn)
(insert insn)
(delete-char insn)))
(while nbls
(setq pre (cdr (pop nbls)))
(while (progn
(setq meta (cdr (assoc pre revisions))
prda nil)
(dolist (insn (cdr (assq :insn meta)))
(goto-line (pop insn))
(case (pop insn)
(k (delete-region
(point) (progn (forward-line (car insn))
(point))))
(i (insert (propertize
(car insn)
:vc-rcs-r/d/a
(or prda (setq prda (r/d/a))))))))
(prog1 (not (string= (if nbls (caar nbls) revision) pre))
(setq pre (cdr (assq 'next meta)))))))))
(let ((ht (make-hash-table :test 'eq))
(me (user-login-name))
(maxw 0)
(all-me t)
rda w a)
(goto-char (point-max))
(while (not (bobp))
(forward-line -1)
(setq rda (get-text-property (point) :vc-rcs-r/d/a))
(unless (gethash rda ht)
(setq a (aref rda 2)
all-me (and all-me (string= a me)))
(puthash rda (setq w (+ (length (aref rda 0))
(length a)))
ht)
(setq maxw (max w maxw))))
(let ((padding (make-string maxw 32)))
(flet ((pad (w) (substring-no-properties padding w))
(render (rda &rest ls)
(propertize
(apply 'concat
(format-time-string "%Y-%m-%d" (aref rda 1))
" "
(aref rda 0)
ls)
:vc-annotate-prefix t
:vc-rcs-r/d/a rda)))
(maphash
(if all-me
(lambda (rda w)
(puthash rda (render rda (pad w) ": ") ht))
(lambda (rda w)
(puthash rda (render rda " " (pad w) " " (aref rda 2) ": ") ht)))
ht)))
(while (not (eobp))
(insert (gethash (get-text-property (point) :vc-rcs-r/d/a) ht))
(forward-line 1))))
(defun vc-rcs-annotate-current-time ()
"Return the current time, based at midnight of the current day, and
encoded as fractional days."
(vc-annotate-convert-time
(apply 'encode-time 0 0 0 (nthcdr 3 (decode-time (current-time))))))
(defun vc-rcs-annotate-time ()
"Return the time of the next annotation (as fraction of days)
systime, or nil if there is none. Also, reposition point."
(unless (eobp)
(prog1 (vc-annotate-convert-time
(aref (get-text-property (point) :vc-rcs-r/d/a) 1))
(goto-char (next-single-property-change (point) :vc-annotate-prefix)))))
(defun vc-rcs-annotate-extract-revision-at-line ()
(aref (get-text-property (point) :vc-rcs-r/d/a) 0))
(defun vc-rcs-assign-name (file name)
"Assign to FILE's latest version a given NAME."
(vc-do-command nil 0 "rcs" (vc-name file) (concat "-n" name ":")))
(defun vc-rcs-check-headers ()
"Check if the current file has any headers in it."
(save-excursion
(goto-char (point-min))
(re-search-forward "\\$[A-Za-z\300-\326\330-\366\370-\377]+\
\\(: [\t -#%-\176\240-\377]*\\)?\\$" nil t)))
(defun vc-rcs-clear-headers ()
"Implementation of vc-clear-headers for RCS."
(let ((case-fold-search nil))
(goto-char (point-min))
(while (re-search-forward
(concat "\\$\\(Author\\|Date\\|Header\\|Id\\|Locker\\|Name\\|"
"RCSfile\\|Revision\\|Source\\|State\\): [^$\n]+\\$")
nil t)
(replace-match "$\\1$"))))
(defun vc-rcs-rename-file (old new)
(vc-rename-master (vc-name old) new vc-rcs-master-templates))
(defun vc-rcs-workfile-is-newer (file)
"Return non-nil if FILE is newer than its RCS master.
This likely means that FILE has been changed with respect
to its master version."
(let ((file-time (nth 5 (file-attributes file)))
(master-time (nth 5 (file-attributes (vc-name file)))))
(or (> (nth 0 file-time) (nth 0 master-time))
(and (= (nth 0 file-time) (nth 0 master-time))
(> (nth 1 file-time) (nth 1 master-time))))))
(defun vc-rcs-find-most-recent-rev (branch)
"Find most recent revision on BRANCH."
(goto-char (point-min))
(let ((latest-rev -1) value)
(while (re-search-forward (concat "^\\(" (regexp-quote branch)
"\\.\\([0-9]+\\)\\)\ndate[ \t]+[0-9.]+;")
nil t)
(let ((rev (string-to-number (match-string 2))))
(when (< latest-rev rev)
(setq latest-rev rev)
(setq value (match-string 1)))))
(or value
(vc-branch-part branch))))
(defun vc-rcs-fetch-master-state (file &optional workfile-version)
"Compute the master file's idea of the state of FILE.
If a WORKFILE-VERSION is given, compute the state of that version,
otherwise determine the workfile version based on the master file.
This function sets the properties `vc-workfile-version' and
`vc-checkout-model' to their correct values, based on the master
file."
(with-temp-buffer
(if (or (not (vc-insert-file (vc-name file) "^[0-9]"))
(progn (goto-char (point-min))
(not (looking-at "^head[ \t\n]+[^;]+;$"))))
(error "File %s is not an RCS master file" (vc-name file)))
(let ((workfile-is-latest nil)
(default-branch (vc-parse-buffer "^branch[ \t\n]+\\([^;]*\\);" 1)))
(vc-file-setprop file 'vc-rcs-default-branch default-branch)
(unless workfile-version
(cond
((or (not default-branch) (string= "" default-branch))
(setq workfile-version
(vc-parse-buffer "^head[ \t\n]+\\([^;]+\\);" 1))
(setq workfile-is-latest t))
((string-match "^[0-9]+\\.[0-9]+\\(\\.[0-9]+\\.[0-9]+\\)*$"
default-branch)
(setq workfile-version default-branch))
(t (vc-insert-file (vc-name file) "^desc")
(setq workfile-version
(vc-rcs-find-most-recent-rev default-branch))
(setq workfile-is-latest t)))
(vc-file-setprop file 'vc-workfile-version workfile-version))
(goto-char (point-min))
(vc-file-setprop file 'vc-checkout-model
(if (re-search-forward ";[ \t\n]*strict;" nil t)
'locking 'implicit))
(goto-char (point-min))
(let ((locking-user
(vc-parse-buffer (concat "^locks[ \t\n]+[^;]*[ \t\n]+\\([^:]+\\):"
(regexp-quote workfile-version)
"[^0-9.]")
1)))
(cond
((not locking-user)
(if (or workfile-is-latest
(vc-rcs-latest-on-branch-p file workfile-version))
'up-to-date
'needs-patch))
((and (stringp locking-user)
(string= locking-user (vc-user-login-name file)))
(if (or (eq (vc-checkout-model file) 'locking)
workfile-is-latest
(vc-rcs-latest-on-branch-p file workfile-version))
'edited
'needs-merge))
((stringp locking-user)
locking-user)
(t
(error "Error getting state of RCS file")))))))
(defun vc-rcs-consult-headers (file)
"Search for RCS headers in FILE, and set properties accordingly.
Returns: nil if no headers were found
'rev if a workfile revision was found
'rev-and-lock if revision and lock info was found"
(cond
((not (get-file-buffer file)) nil)
((let (status version locking-user)
(save-excursion
(set-buffer (get-file-buffer file))
(goto-char (point-min))
(cond
((or (and (search-forward "$Id\ : " nil t)
(looking-at "[^ ]+ \\([0-9.]+\\) "))
(and (progn (goto-char (point-min))
(search-forward "$Header\ : " nil t))
(looking-at "[^ ]+ \\([0-9.]+\\) ")))
(goto-char (match-end 0))
(setq version (match-string-no-properties 1))
(cond
((looking-at
(concat "[0-9]+[/-][01][0-9][/-][0-3][0-9] " "[0-2][0-9]:[0-5][0-9]+:[0-6][0-9]+\\([+-][0-9:]+\\)? " "[^ ]+ [^ ]+ ")) (goto-char (match-end 0)) (cond
((looking-at "\\$")
(setq locking-user 'none)
(setq status 'rev-and-lock))
((looking-at "\\([^ ]+\\) \\$")
(setq locking-user (match-string-no-properties 1))
(setq status 'rev-and-lock))
(nil)))
(nil)))
((re-search-forward (concat "\\$"
"Revision: \\([0-9.]+\\) \\$")
nil t)
(setq version (match-string-no-properties 1))
(goto-char (point-min))
(if (re-search-forward (concat "\\$" "Locker:") nil t)
(cond ((looking-at " \\([^ ]+\\) \\$")
(setq locking-user (match-string-no-properties 1))
(setq status 'rev-and-lock))
((looking-at " *\\$")
(setq locking-user 'none)
(setq status 'rev-and-lock))
(t
(setq locking-user 'none)
(setq status 'rev-and-lock)))
(setq status 'rev)))
(t nil)))
(if status (vc-file-setprop file 'vc-workfile-version version))
(and (eq status 'rev-and-lock)
(vc-file-setprop file 'vc-state
(cond
((eq locking-user 'none) 'up-to-date)
((string= locking-user (vc-user-login-name file))
'edited)
(t locking-user)))
(not (vc-mistrust-permissions file))
(vc-up-to-date-p file)
(if (string-match ".r-..-..-." (nth 8 (file-attributes file)))
(vc-file-setprop file 'vc-checkout-model 'locking)
(vc-file-setprop file 'vc-checkout-model 'implicit)))
status))))
(defun vc-release-greater-or-equal (r1 r2)
"Compare release numbers, represented as strings.
Release components are assumed cardinal numbers, not decimal fractions
\(5.10 is a higher release than 5.9\). Omitted fields are considered
lower \(5.6.7 is earlier than 5.6.7.1\). Comparison runs till the end
of the string is found, or a non-numeric component shows up \(5.6.7 is
earlier than \"5.6.7 beta\", which is probably not what you want in
some cases\). This code is suitable for existing RCS release numbers.
CVS releases are handled reasonably, too \(1.3 < 1.4* < 1.5\)."
(let (v1 v2 i1 i2)
(catch 'done
(or (and (string-match "^\\.?\\([0-9]+\\)" r1)
(setq i1 (match-end 0))
(setq v1 (string-to-number (match-string 1 r1)))
(or (and (string-match "^\\.?\\([0-9]+\\)" r2)
(setq i2 (match-end 0))
(setq v2 (string-to-number (match-string 1 r2)))
(if (> v1 v2) (throw 'done t)
(if (< v1 v2) (throw 'done nil)
(throw 'done
(vc-release-greater-or-equal
(substring r1 i1)
(substring r2 i2)))))))
(throw 'done t)))
(or (and (string-match "^\\.?\\([0-9]+\\)" r2)
(throw 'done nil))
(throw 'done t)))))
(defun vc-rcs-release-p (release)
"Return t if we have RELEASE or better."
(let ((installation (vc-rcs-system-release)))
(if (and installation
(not (eq installation 'unknown)))
(vc-release-greater-or-equal installation release))))
(defun vc-rcs-system-release ()
"Return the RCS release installed on this system, as a string.
Return symbol UNKNOWN if the release cannot be deducted. The user can
override this using variable `vc-rcs-release'.
If the user has not set variable `vc-rcs-release' and it is nil,
variable `vc-rcs-release' is set to the returned value."
(or vc-rcs-release
(setq vc-rcs-release
(or (and (zerop (vc-do-command nil nil "rcs" nil "-V"))
(with-current-buffer (get-buffer "*vc*")
(vc-parse-buffer "^RCS version \\([0-9.]+ *.*\\)" 1)))
'unknown))))
(defun vc-rcs-set-non-strict-locking (file)
(vc-do-command nil 0 "rcs" file "-U")
(vc-file-setprop file 'vc-checkout-model 'implicit)
(set-file-modes file (logior (file-modes file) 128)))
(defun vc-rcs-set-default-branch (file branch)
(vc-do-command nil 0 "rcs" (vc-name file) (concat "-b" branch))
(vc-file-setprop file 'vc-rcs-default-branch branch))
(defun vc-rcs-parse (&optional buffer)
"Parse current buffer, presumed to be in RCS-style masterfile format.
Optional arg BUFFER specifies another buffer to parse. Return an alist
of two elements, w/ keys `headers' and `revisions' and values in turn
sub-alists. For `headers', the values unless otherwise specified are
strings and the keys are:
desc -- description
head -- latest revision
branch -- the branch the \"head revision\" lies on;
absent if the head revision lies on the trunk
access -- ???
symbols -- sub-alist of (SYMBOL . REVISION) elements
locks -- if file is checked out, something like \"ttn:1.7\"
strict -- t if \"strict locking\" is in effect, otherwise nil
comment -- may be absent; typically something like \"# \" or \"; \"
expand -- may be absent; ???
For `revisions', the car is REVISION (string), the cdr a sub-alist,
with string values (unless otherwise specified) and keys:
date -- a time value (like that returned by `encode-time'); as a
special case, a year value less than 100 is augmented by 1900
author -- username
state -- typically \"Exp\" or \"Rel\"
branches -- list of revisions that begin branches from this revision
next -- on the trunk: the chronologically-preceding revision, or \"\";
on a branch: the chronologically-following revision, or \"\"
log -- change log entry
text -- for the head revision on the trunk, the body of the file;
other revisions have `:insn' instead
:insn -- for non-head revisions, a list of parsed instructions
in one of two forms, in both cases START meaning \"first
go to line START\":
- `(START k COUNT)' -- kill COUNT lines
- `(START i TEXT)' -- insert TEXT (a string)
The list is in descending order by START.
The `:insn' key is a keyword to distinguish it as a vc-rcs.el extension."
(setq buffer (get-buffer (or buffer (current-buffer))))
(set-buffer buffer)
(let ((desc nil) (headers nil) (revs nil)
context
tok
b e
@-holes)
(flet ((sw () (skip-chars-forward " \t\n")) (at (tag) (save-excursion (eq tag (read buffer))))
(to-eol () (buffer-substring-no-properties
(point) (progn (forward-line 1)
(1- (point)))))
(to-semi () (setq b (point)
e (progn (search-forward ";")
(1- (point)))))
(to-one@ () (setq @-holes nil
b (progn (search-forward "@") (point))
e (progn (while (and (search-forward "@")
(= ?@ (char-after))
(progn
(push (point) @-holes)
(forward-char 1)
(push (point) @-holes))))
(1- (point)))))
(tok+val (set-b+e name &optional proc)
(unless (eq name (setq tok (read buffer)))
(error "Missing `%s' while parsing %s" name context))
(sw)
(funcall set-b+e)
(cons tok (if proc
(funcall proc)
(buffer-substring-no-properties b e))))
(k-semi (name &optional proc) (tok+val 'to-semi name proc))
(gather () (let ((pairs `(,e ,@@-holes ,b))
acc)
(while pairs
(push (buffer-substring-no-properties
(cadr pairs) (car pairs))
acc)
(setq pairs (cddr pairs)))
(apply 'concat acc)))
(k-one@ (name &optional later) (tok+val 'to-one@ name
(if later
(lambda () t)
'gather))))
(save-excursion
(goto-char (point-min))
(setq context 'headers)
(flet ((hpush (name &optional proc)
(push (k-semi name proc) headers)))
(hpush 'head)
(when (at 'branch)
(hpush 'branch))
(hpush 'access)
(hpush 'symbols
(lambda ()
(mapcar (lambda (together)
(let ((two (split-string together ":")))
(setcar two (intern (car two)))
(setcdr two (cadr two))
two))
(split-string
(buffer-substring-no-properties b e)))))
(hpush 'locks))
(push `(strict . ,(when (at 'strict)
(search-forward ";")
t))
headers)
(when (at 'comment)
(push (k-one@ 'comment) headers)
(search-forward ";"))
(when (at 'expand)
(push (k-one@ 'expand) headers)
(search-forward ";"))
(setq headers (nreverse headers))
(sw) (setq context 'rev-headers)
(while (looking-at "[0-9]")
(push `(,(to-eol)
,(k-semi 'date
(lambda ()
(let ((ls (mapcar 'string-to-number
(split-string
(buffer-substring-no-properties
b e)
"\\."))))
(when (< (car ls) 100)
(setcar ls (+ 1900 (car ls))))
(apply 'encode-time (nreverse ls)))))
,@(mapcar 'k-semi '(author state))
,(k-semi 'branches
(lambda ()
(split-string
(buffer-substring-no-properties b e))))
,(k-semi 'next))
revs)
(sw))
(setq revs (nreverse revs))
(sw) (setq context 'desc
desc (k-one@ 'desc))
(let (acc
rev
cmd start act
asc
sub)
(flet ((incg (beg end) (let ((b beg) (e end) @-holes)
(while (and asc (< (car asc) e))
(push (pop asc) @-holes))
(unless asc
(setq sub 'buffer-substring-no-properties))
(gather))))
(while (and (sw)
(not (eobp))
(setq context (to-eol)
rev (or (assoc context revs)
(error "Rev `%s' has body but no head"
context))))
(push (k-one@ 'log) (cdr rev))
(push (k-one@ 'text t) (cdr rev))
(if (string= context (cdr (assq 'head headers)))
(setcdr (cadr rev) (gather))
(if @-holes
(setq asc (nreverse @-holes)
sub 'incg)
(setq sub 'buffer-substring-no-properties))
(goto-char b)
(setq acc nil)
(while (< (point) e)
(forward-char 1)
(setq cmd (char-before)
start (read (current-buffer))
act (read (current-buffer)))
(forward-char 1)
(push (case cmd
(?d
`(,start k ,act))
(?a
`(,(1+ start) i
,(funcall sub (point) (progn (forward-line act)
(point)))))
(t (error "Bad command `%c' in `text' for rev `%s'"
cmd context)))
acc))
(goto-char (1+ e))
(setcar (cdr rev) (cons :insn acc)))))))
`((headers ,desc ,@headers)
(revisions ,@revs)))))
(provide 'vc-rcs)